# 2STDEV.MAC
#
# Conducts F procedures for comparing two population standard deviations
#
# Macro is for MINITAB for Windows, release 10 and above
# Written by: Neil A. Weiss
# Date: 07/30/98
#
# Revision history:
#   04/04/00: Revised to account for changes in Release 13 for what is
#             acceptable syntax in Minitab macros.

MACRO
TWOSTDEV X1 X2              # DATA

MCOLUMN X1 X2 R H0 HYPS ALTSIGN D.1-D.7 UC LC UL LL PCT LPAREN RPAREN COMMA
MCONSTANT df1 df2 s1 s2 f ans p k alt n1 n2 c k1 k2 var1 var2

NOTITLES
BRIEF 2
NOTE
NOTE This macro performs a hypothesis test and/or obtains 
NOTE a confidence interval for two population standard deviations.
NOTE
BRIEF 0
KKNAME var1 X1
KKNAME var2 X2
COPY var1 var2 D.7
NAME D.7 'Variable'
LET n1=N(X1)
LET n2=N(X2)
COPY n1 n2 D.1
NAME D.1 'n'
NTOA D.1 D.1
LET df1=N(X1)-1
LET df2=N(X2)-1
LET s1=STDEV(X1)
LET s2=STDEV(X2)
COPY s1 s2 D.2
NAME D.2 'StDev' 
NTOA D.2 D.2;
 DECIMALS 3.
BRIEF 2
NOTE Do you want to perform a hypothesis test (Y/N)?
NOTE
BRIEF 0
YESNO ans
IF ans=0
  GOTO 1
ENDIF
READ H0;
  FORMAT (A30).
F-Test of sigma1 = sigma2 (vs 
END
LET f=(s1/s2)**2
COPY f D.3
NAME D.3 'F'
NTOA D.3 D.3;
  DECIMALS 2.
NOTE
BRIEF 2
NOTE
NOTE Enter 0, 1, or -1, respectively, for a two-tailed, right-tailed,
NOTE or left-tailed test.
NOTE
BRIEF 0
SET R;
  FILE 'TERMINAL';
  NOBS 1.
END
COPY R alt
# NOTE THAT IN THE SET COMMANDS BELOW USED WITH "FORMAT," WE PUT THE 
# THE ALPHA DATA AND THE "END" FLUSH LEFT. THIS *MUST* BE DONE!
IF alt=0
  SET ALTSIGN;
    FORMAT (A6).
not =)
END
  BRIEF 2
ELSEIF alt=1
  SET ALTSIGN;
    FORMAT (A2).
>)
END
ELSE
  SET ALTSIGN;
    FORMAT (A2).
<) 
END
ENDIF
CONCAT H0 ALTSIGN HYPS
BRIEF 2
NOTE
PRINT HYPS;
  FORMAT (A36).
BRIEF 0
CDF f p;
F df1 df2.
IF alt=0
 LET k=1-p
 IF k<p
  LET p=k
 ENDIF
 LET p=2*p
ELSEIF alt=1
 LET p=1-p
ENDIF
COPY p D.4
NAME D.4 'P'
NTOA D.4 D.4;
 DECIMALS 3.
BRIEF 2
PRINT D.7 D.1-D.4
MLABEL 1
BRIEF 2
NOTE
NOTE
NOTE Do you want a confidence interval (Y/N)?
NOTE
BRIEF 0
YESNO ans
IF ans=0
 BRIEF 2
 TITLES
 EXIT
ENDIF
BRIEF 2
NOTE
NOTE Enter the confidence level, as a percentage.
NOTE
BRIEF 0
SET R;
 FILE 'TERMINAL';
 NOBS 1.
COPY R c
NTOA R R;
 DECIMALS 1.
READ PCT LPAREN RPAREN COMMA;
 FORMAT (3A1,A2).
%(), 
END
CONC R PCT D.5
NAME D.5 'Level'
LET k1=(100-c)/200  # ALPHA/2
LET k2=1-k1         # 1-ALPHA/2
INVCDF k1 UC;
 F df1 df2.
INVCDF k2 LC;
 F df1 df2.
LET LL=1/SQRT(LC)*s1/s2
LET UL=1/SQRT(UC)*s1/s2
NTOA LL LL;
 DECIMALS 3.
NTOA UL UL;
 DECIMALS 3.
CONCAT LPAREN LL COMMA UL RPAREN D.6
NAME D.6 'CI for ratio'
BRIEF 2
NOTE
PRINT D.7 D.1 D.2 D.5 D.6

TITLES
BRIEF 2

ENDMACRO